Ce script est exécuté lorsque l'installation commence, avant d'installer les différents produits du SAP GUI.

L'éditeur de script intégré n'étant pas très convivial, il est préférable d'utiliser un fichier vbs externe que l'on appelle depuis l'installeur. Voici le script à utiliser dans l'événement On Installation Start qui va appeler le fichier CustomerFiles\OnInstallationStart.vbs

ScriptFile = NwEngine.Variables.ResolveString("%SapSrcDir%\CustomerFiles\OnInstallationStart.vbs")
 
If NwEngine.Shell.FileExist( ScriptFile ) Then
  NwEngine.Shell.Execute ScriptFile, vbFalse
Else
  strLog = "'" & ScriptFile & "' not found!"
  NwEngine.Context.Log.WriteError strLog
End If

Et voici le contenu du script OnInstallationStart.vbs

' Récupére le répertoire courant
CurrentDir = CreateObject("Scripting.FileSystemObject").GetParentFolderName(WScript.ScriptFullName)
CurrentDir = CurrentDir & "\" 
 
' Création d'un objet FileSystem
Set oFs = CreateObject("Scripting.FileSystemObject")
' Création d'un objet Shell
Set oShell = WScript.CreateObject( "WScript.Shell" )
 
' Si le répertoire de logs n'existe pas, le crée
If Not oFs.FolderExists("C:\Logs") Then
  oFs.CreateFolder("C:\Logs")
End If
 
' Création du fichier de log (si le fichier existe, il sera supprimé et remplacé par un nouveau fichier
Set oLog = oFs.CreateTextFile("C:\Logs\OnInstallationStart.txt", True)
 
' Signale l'exécution du script
oLog.WriteLine("")
oLog.WriteLine("Client SAP - Exécution du script OnInstallationStart.vbs")
' Indique le répertoire dans lequel on se trouve
oLog.WriteLine("Exécution dans le répertoire: " & CurrentDir)
 
oLog.WriteLine("")
oLog.WriteLine(" Installation des prérequis")
oLog.WriteLine("============================")
 
' Installation de WebViewer2
oLog.WriteLine("")
oLog.WriteLine(" Installation de WebViewer2")
oLog.WriteLine("----------------------------")
' Ajoute le nom de l'exécutable au répertoire courant
strCmdLine = CurrentDir & "MicrosoftEdgeWebView2RuntimeInstallerX64.exe" 
' Indique dans le log la ligne de commande qui va être utilisée
oLog.WriteLine("strCmdLine = " & strCmdLine & " /silent /install")
' Appel du programme d'installation
RetCode = oShell.Run("""" & strCmdLine & """ /silent /install", 0, True)
' Ecriture dans le log du code retour
oLog.WriteLine("RetCode: " & RetCode)
 
' Fermeture du fichier de log
oLog.Close
 
Set oShell = Nothing
Set oFs = Nothing