Ce script s'exécute à la fin de l'installation ou à la fin d'une mise à jour, c'est pour cela qu'un seul script va être utilisé pour ces deux événements.

ScriptFile = NwEngine.Variables.ResolveString("%SapSrcDir%\CustomerFiles\OnInstallationOrUpdateEnd.vbs")
 
If NwEngine.Shell.FileExist( ScriptFile ) Then
  NwEngine.Shell.Execute ScriptFile, vbFalse
Else
  strLog = "'" & ScriptFile & "' not found!"
  NwEngine.Context.Log.WriteError strLog
End If

Voici le contenu du script OnInstallationOrUpdateEnd.vbs

' Récupére le répertoire courant
CurrentDir = CreateObject("Scripting.FileSystemObject").GetParentFolderName(WScript.ScriptFullName)
CurrentDir = CurrentDir & "\" 
 
' Création d'un objet FileSystem
Set oFs = CreateObject("Scripting.FileSystemObject")
' Création d'un objet Shell
Set oShell = WScript.CreateObject( "WScript.Shell" )
' Pour l'accès aux variables d'environnemnt
Set oEnv = oShell.Environment("System")
 
' Si le répertoire de logs n'existe pas, le crée
If Not oFs.FolderExists("C:\Logs") Then
  oFs.CreateFolder("C:\Logs")
End If
 
' Création du fichier de log (si le fichier existe, il sera supprimé et remplacé par un nouveau fichier
Set oLog = oFs.CreateTextFile("C:\Logs\OnInstallationOrUpdateEnd.txt", True)
 
' Signale l'exécution du script
oLog.WriteLine("")
oLog.WriteLine("Client SAP - Exécution du script OnInstallationOrUpdateEnd.vbs")
' Indique le répertoire dans lequel on se trouve
oLog.WriteLine("Exécution dans le répertoire: " & CurrentDir)
 
oLog.WriteLine("")
oLog.WriteLine(" Activités post installation")
oLog.WriteLine("=============================")
 
' Kerberos
Dim strSrcFile, strSrcFilex86, strDstFile, strDstFilex86
oLog.WriteLine("")
oLog.WriteLine(" Copie des librairies Kerberos")
oLog.WriteLine("-------------------------------")
 
' Répertoire pour la librairie 64 bits
strDstFile    = oShell.ExpandEnvironmentStrings("%ProgramFiles%")
strDstFile    = strDstFile & "\SAP"
If Not oFs.FolderExists(strDstFile) Then
  oFs.CreateFolder(strDstFile)
End If
strDstFile    = strDstFile & "\Kerberos"
If Not oFs.FolderExists(strDstFile) Then
  oFs.CreateFolder(strDstFile)
End If
strDstFile    = strDstFile & "\"
 
' Répertoire pour la librairie 32 bits
strDstFilex86 = oShell.ExpandEnvironmentStrings("%ProgramFiles(x86)%")
strDstFilex86 = strDstFilex86 & "\SAP"
If Not oFs.FolderExists(strDstFilex86) Then
  oFs.CreateFolder(strDstFilex86)
End If
strDstFilex86 = strDstFilex86 & "\Kerberos"
If Not oFs.FolderExists(strDstFilex86) Then
  oFs.CreateFolder(strDstFilex86)
End If
strDstFilex86 = strDstFilex86 & "\"
 
' Chemins des différents fichiers
strSrcFile    = CurrentDir    & "gx64krb5.dll"
strSrcFilex86 = CurrentDir    & "gsskrb5.dll" 
strDstFile    = strDstFile    & "gx64krb5.dll"
strDstFilex86 = strDstFilex86 & "gsskrb5.dll" 
 
' Copie des fichiers
oLog.WriteLine("Copie du fichier '" & strSrcFile &"' vers '" & strDstFile & "'") 
oFs.CopyFile strSrcFile, strDstFile, True
oLog.WriteLine("Copie du fichier '" & strSrcFilex86 &"' vers '" & strDstFilex86 & "'") 
oFs.CopyFile strSrcFilex86, strDstFilex86, True 
 
oLog.WriteLine("")
 
oLog.WriteLine(" Configuration des variables d'environnemnt SSO")
oLog.WriteLine("------------------------------------------------")
 
oLog.WriteLine("SET SNC_LIB=" & strDstFilex86) 
oEnv("SNC_LIB") = strDstFilex86
 
oLog.WriteLine("SET SNC_LIB_64=" & strDstFile) 
oEnv("SNC_LIB_64") = strDstFile
 
' Fermeture du fichier de log
oLog.Close
 
Set oEnv = Nothing
Set oShell = Nothing
Set oFs = Nothing

• Gérer raccourcis sur le bureau
• Gérer raccourcis dans le menu démarrer